package {
   
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Shader;
    import flash.display.ShaderJob;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.filters.BlurFilter;
    import flash.filters.ColorMatrixFilter;
    import flash.geom.Point;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.utils.ByteArray;
   
    [SWF(width=376, height=160, backgroundColor=0×0)]
   
    public class SubtractTv extends Sprite {
       
        [Embed(source="../assets/kutu.pbj", mimeType="application/octet-stream")]
        private var pbj:Class;
       
        private var wid:uint = stage.stageWidth;
        private var hei:uint = stage.stageHeight;
       
        private var video:Video;
        private var nc:NetConnection;
        private var ns:NetStream;
       
        private var bmp1:BitmapData;
        private var bmp2:BitmapData;
        private var bmp3:BitmapData;
        private var out:BitmapData;
        private var bmp:Bitmap;
       
        private var shader:Shader;
        private var shaderJob:ShaderJob;
       
        private var blur:BlurFilter;
        private var cmf:ColorMatrixFilter;
       
        public function SubtractTv() {
            nc = new NetConnection();
            nc.connect(null);
            ns = new NetStream(nc);
            ns.client = new Object();
            ns.play("video.f4v");
           
            video = new Video(wid, hei);
            video.attachNetStream(ns);
           
            bmp1 = new BitmapData(wid, hei, true);
            bmp2 = bmp1.clone();
            bmp3 = bmp1.clone();
            out = bmp1.clone();
            bmp = new Bitmap(out, "auto", true);
            addChild(bmp);
           
            shader = new Shader(new pbj() as ByteArray);
            shader.data.src.input = bmp1;
            shader.data.src2.input = bmp2;
            createShaderJob();
           
            addEventListener(Event.ENTER_FRAME, onEnterFrame);
           
            blur = new BlurFilter(3, 3, 3);
            cmf = new ColorMatrixFilter([   1, 0, 0, 0, 0,
                                            0, 1, 0, 0, 0,
                                            0, 0, 1, 0, 0,
                                            0, 0, 0, 1, -10]);
        }
       
        private function onEnterFrame(e:Event):void {
            if (shaderJob.progress != 1) return;
           
            bmp2.draw(bmp1);
            try {
                bmp1.draw(video);
            } catch(e:Error) {}
           
            createShaderJob();
           
            out.applyFilter(out, out.rect, new Point(), blur);
            out.applyFilter(out, out.rect, new Point(), cmf);
            out.draw(bmp3);
        }
       
        private function createShaderJob():void {
            shaderJob = new ShaderJob(shader, bmp3, wid, hei);
            shaderJob.start();
        }
       
    }
}

package {
    import flash.display.Sprite;
    import flash.events.SampleDataEvent;
    import flash.media.Sound;
    import flash.media.SoundTransform;
   
    [SWF(width="550", height="400", backgroundColor="#000000")]
   
    public class StayTogether extends Sprite {
        private var sound:Sound;
        private var noiseSolo:Number = 0;
        private var noiseBass:Number = 0;
        private var now:int = 0;
        private var hold:int = 0;
        private var speed:int = 5;
        private var soloArr:Array;
        private var bassArr:Array;
       
        public function StayTogether() {
            // stay together for the kids
            var str:String =
            "d-4/d-4/d-4/a-4/d-4/d-4/f#4/d-4/" +
            "c#4/d-4/c#4/a-4/c#4/d-4/f#4/d-4/" +
            "b-3/d-4/b-3/f#4/b-3/d-4/g-4/d-4/" +
            "a-3/e-4/a-3/f#4/g-4/f#4/e-4/d-4/" +
            "d-4/d-4/d-4/a-4/d-4/d-4/f#4/d-4/" +
            "c#4/d-4/c#4/a-4/c#4/d-4/f#4/d-4/" +
            "b-3/d-4/b-3/f#4/b-3/d-4/g-4/d-4/" +
            "a-3/e-4/a-3/f#4/g-4/f#4/e-4/d-4/" +
           
            "d-4/d-4/d-5=/d-5/d-4/d-4/d-5=/d-5/d-4/d-4/d-5=/d-5/d-4/d-4/d-5=/d-5/" +
            "c#4/c#4/d-5=/d-5/c#4/c#4/d-5=/d-5/c#4/c#4/d-5=/d-5/c#4/c#4/d-5=/d-5/" +
            "a-3/a-3/d-5=/d-5/a-3/a-3/d-5=/d-5/a-3/a-3/d-5=/d-5/a-3/a-3/d-5=/d-5/" +
            "a-3/a-3/e-5=/e-5/a-3/a-3/e-5=/e-5/a-3/a-3/c#5=/c#5/a-3/a-3/c#5=/c#5/" +
           
            "d-4/d-4/d-5=/d-4/d-4/d-4/d-5=/d-4/d-4/d-4/d-5=/d-4/d-4/d-4/d-5=/d-4/" +
            "c#4/c#4/d-5=/c#4/c#4/c#4/d-5=/c#4/c#4/c#4/d-5=/c#4/c#4/c#4/d-5=/c#4/" +
            "a-3/a-3/d-5=/a-3/a-3/a-3/d-5=/a-3/a-3/a-3/d-5=/a-3/a-3/a-3/d-5=/a-3/" +
            "a-3/a-3/e-5=/a-3/a-3/a-3/e-5=/a-3/a-3/a-3/c#5=/a-3/a-3/a-3/c#5=/a-3/" +
           
            "d-4/d-4/d-4/d-4/d-4/d-4/d-4/d-4/d-4/d-4/d-4/d-4/d-4/d-4/d-4/d-4/" +
            "c#4/c#4/c#4/c#4/c#4/c#4/c#4/c#4/c#4/c#4/c#4/c#4/c#4/c#4/b-3/c#4/" +
            "d-4/d-4/d-4/d-4/d-4/d-4/d-4/d-4/d-4/d-4/d-4/d-4/d-4/d-4/d-4/d-4/" +
            "c#4/c#4/c#4/c#4/c#4/c#4/c#4/c#4/c#4/c#4/c#4/c#4/c#4/c#4/b-3/c#4";
            soloArr = notesToHertz(str);
           
            // stay together for the kids
            str =
            "d-3/d-3/d-3/d-3/d-3/d-3/d-3/d-3/" +
            "c#3/c#3/c#3/c#3/c#3/c#3/c#3/c#3/" +
            "b-2/b-2/b-2/b-2/b-2/b-2/b-2/b-2/" +
            "a-2/a-2/a-2/a-2/a-2/a-2/a-2/a-2/" +
            "d-3/d-3/d-3/d-3/d-3/d-3/d-3/d-3/" +
            "c#3/c#3/c#3/c#3/c#3/c#3/c#3/c#3/" +
            "b-2/b-2/b-2/b-2/b-2/b-2/b-2/b-2/" +
            "a-2/a-2/a-2/a-2/a-2/a-2/a-2/a-2/" +
           
            "d-3/d-3/a-4=/a-4/d-3/d-3/a-4=/a-4/d-3/d-3/a-4=/a-4/d-3/d-3/a-4=/a-4/" +
            "c#3/c#3/a-4=/a-4/c#3/c#3/a-4=/a-4/c#3/c#3/a-4=/a-4/c#3/c#3/a-4=/a-4/" +
            "a-2/a-2/a-4=/a-4/a-2/a-2/a-4=/a-4/a-2/a-2/a-4=/a-4/a-2/a-2/a-4=/a-4/" +
            "a-2/a-2/a-4=/a-4/a-2/a-2/a-4=/a-4/a-2/a-2/a-4=/a-4/a-2/a-2/a-4=/a-4/" +
           
            "d-3/d-3/a-4=/d-3/d-3/d-3/a-4=/d-3/d-3/d-3/a-4=/d-3/d-3/d-3/a-4=/d-3/" +
            "c#3/c#3/a-4=/c#3/c#3/c#3/a-4=/c#3/c#3/c#3/a-4=/c#3/c#3/c#3/a-4=/c#3/" +
            "a-2/a-2/a-4=/a-2/a-2/a-2/a-4=/a-2/a-2/a-2/a-4=/a-2/a-2/a-2/a-4=/a-2/" +
            "a-2/a-2/a-4=/a-2/a-2/a-2/a-4=/a-2/a-2/a-2/a-4=/a-2/a-2/a-2/a-4=/a-2/" +
           
            "g-2/g-2/g-2/g-2/g-2/g-2/g-2/g-2/g-2/g-2/g-2/g-2/g-2/g-2/g-2/g-2/" +
            "f#2/f#2/f#2/f#2/f#2/f#2/f#2/f#2/f#2/f#2/f#2/f#2/f#2/f#2/e-2/f#2/" +
            "g-2/g-2/g-2/g-2/g-2/g-2/g-2/g-2/g-2/g-2/g-2/g-2/g-2/g-2/g-2/g-2/" +
            "f#2/f#2/f#2/f#2/f#2/f#2/f#2/f#2/f#2/f#2/f#2/f#2/f#2/f#2/e-2/f#2";
            bassArr = notesToHertz(str);
           
            sound = new Sound();
            sound.addEventListener(SampleDataEvent.SAMPLE_DATA, onCallback);
            sound.play(0, 0, new SoundTransform(.25, -.1));
        }
       
        private function onCallback(e:SampleDataEvent):void {
            var sample1:Number;
            var sample2:Number;
            var flag:Boolean = hold<speed-soloArr[now].short;
           
            for (var i:uint=0; i<2048; i++){
                noiseSolo += soloArr[now].hz;
                sample1 = noiseSolo * Math.PI;
                sample1 = Math.min(1, Math.tan(sample1));
           
                noiseBass += bassArr[now].hz;
                sample2 = noiseBass * Math.PI;
                sample2 = Math.min(1, Math.tan(sample2));
               
                if (!flag && i>=1024) {
                    sample1 = 0;
                    sample2 = 0;
                }
               
                e.data.writeFloat(sample1);
                e.data.writeFloat(sample2);
            }
           
            hold++;
            if (hold==speed) {
                hold = 0;
                now++;
                now==soloArr.length ? now=0 : null;
            }
        }
       
        private function notesToHertz(str:String):Array {
            var str:String = str.toUpperCase();
            var arr:Array = str.split("/");
           
            for (var i:uint=0; i<arr.length; i++){
                var a:Array = arr[i].split("");
                var num:Number;
                if (a[1] == "#") {
                    num = Notes[a[0]+"_"];
                } else {
                    num = Notes[a[0]];
                }
                num = 2 + num + 12*Number(a[2]) - 12*6;
                var hz:Number = Math.pow(2, num/12) * 440;
                hz /= 44100;
               
                var short:int;
                if (a[3]=="=") short = 0;
                    else short = 1;
               
                arr[i] = {hz:hz, short:short};
            }
            return arr;
        }
    }
}

package {
    public class Notes {
        public static const C:Number = 1;
        public static const C_:Number = 2;
        public static const D:Number = 3;
        public static const D_:Number = 4;
        public static const E:Number = 5;
        public static const F:Number = 6;
        public static const F_:Number = 7;
        public static const G:Number = 8;
        public static const G_:Number = 9;
        public static const A:Number = 10;
        public static const A_:Number = 11;
        public static const B:Number = 12;
       
        public function Notes() {}
    }
}